SCRATCHBRAIN.BLOG ver.1// Flashでオブジェクト指向言語ActionScript3.0はじめました

blog バージョン２

2007-04-26T17:28:12Z

SCRATCHBRAIN.BLOG ver.2に切り替えました。ひきつづき、Flash、ActionScript3.0の話題を中心に、ApolloやFlexについても取り上げたいと思っていますので、今後ともよろしくお願いします。

8-1-5.カスタムクラスからのイベント送出その２

2007-04-26T11:00:00Z

『8-1-4.カスタムクラスからのイベント送出その１』のつづき。その１ではEventDispatcherクラスを継承する場合についてまとめました。ここではIEventDispatcherインターフェイスを使う場合を取り上げたいと思います。]]> IEventDispatcherインターフェイスの実装まず、IEventDispatcherインターフェイスを実装したクラスを作成し、各メソッドを定義します。インターフェイスについては『5-4.インターフェイス』をご覧下さい。

package {
 import flash.events.IEventDispatcher;
 import flash.events.Event;
 import flash.events.EventDispatcher;
 class CustomDispatcher implements IEventDispatcher {
  private var dispatcher:EventDispatcher;
  public function CustomDispatcher() {
   dispatcher = new EventDispatcher(this);
  }
  public function addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void{
   dispatcher.addEventListener(type, listener, useCapture, priority);
  }
  public function dispatchEvent(evt:Event):Boolean{
   return dispatcher.dispatchEvent(evt);
  }
  public function hasEventListener(type:String):Boolean{
   return dispatcher.hasEventListener(type);
  }
  public function removeEventListener(type:String, listener:Function,useCapture:Boolean = false):void{
   dispatcher.removeEventListener(type, listener, useCapture);
  }
  public function willTrigger(type:String):Boolean {
   return dispatcher.willTrigger(type);
  }
  // イベント処理
  public function doAction():void {
   // 処理開始送出
   dispatchEvent(new Event("start"));
   // イベントの内容
   for (var i:int; i < 5 ; i++) {
    trace(i);
   dispatchEvent(new Event("processing"));
   }
   // 処理終了送出
   dispatchEvent(new Event("complete"));
  }
 }
}

CustomDispatcherクラスの使用次に、MainクラスでCustomDispatcherクラスを使ってイベント処理を行ってみます。

package {
 import flash.display.Sprite;
 import flash.events.Event;
 public class Main extends Sprite {
  private var example:CustomDispatcher = new CustomDispatcher();
  public function Main() {
   example = new CustomDispatcher();
   example.addEventListener("start", onStart);
   example.addEventListener("processing", onProcess);
   example.addEventListener("complete", onComplete);
   example.doAction();
  }
  private function onStart(event:Event):void{
   trace("イベント開始");
  }
  private function onProcess(event:Event):void{
   trace("処理中...");
  }
  private function onComplete(event:Event):void{
   trace("イベント終了");
  }
 }
}

出力結果は次のようになります。

イベント開始
0
処理中...
1
処理中...
2
処理中...
3
処理中...
4
処理中...
イベント終了

EventDispatcherクラス継承したほうがやっぱりスマート。それとも間違っているのかな、参考URL Adobe Flex 2 リファレンスガイド IEventDispatcherインターフェイス Adobe Flex 2 ヘルプインターフェイス akihiro kamijo カスタムイベントのディスパッチ

Adobe Video Workshop その２

2007-04-25T05:21:17Z

『Adobe Video Workshop その１』のつづき。 Creating a simple application with components リストとボタンコンポーネントのチュートリアル。次のような内容。]]>

import fl.events.*;
import flash.events.*;
import fl.data.DataProvider;
var dp:DataProvider = new DataProvider();
dp.addItem({label:"tomato"});
dp.addItem({label:"carrot"});
dp.addItem({label:"blueberry"});
dp.addItem({label:"turnip"});
myList.dataProvider = dp;

コンパイルすると、ここまででリストが表示される。（turnipってカブなんだ。）

myList.addEventListener(Event.CHANGE,announceSelect);
myButton.addEventListener(MouseEvent.CLICK,eatItem);
function announceSelect(e:Event):void{
 trace("You have selected item: ", myList.selectedItem.label);
}
function eatItem(e:MouseEvent):void{
 trace("You have eaten item: ", myList.selectedItem.label);
 dp.removeItem(myList.selectedItem);
}

コンパイル。４.Listでアイテムを選ぶと『You have selected item: tomato』とかtraceされる５.Listでアイテムを選んで、Buttonを押すと、選んだアイテムがListから削除される Writing ActionScript for components ボタンコンポーネントを使ったボタンにActionScriptを記述する方法についてのチュートリアル。だいたい次のような内容。１.コンポーネントパネルからステージにButtonをドラッグ２.ステージからボタンを削除（ライブラリにボタンがある）３.ActionScriptパネルを開き、１フレーム目に次のコードを記述する

import fl.controls.Button;
var b:Button = new Button();
addChild(b);

４.コンパイルしてステージにボタンが表示されることを確認して、次の２行を削除する

var b:Button = new Button();
addChild(b);

５.次のコードを記述する

var i:uint = 0;
var j:uint = 0;
var posX:uint = 0;
var posY:uint = 0;
var buttonSize:uint = 25;
while(posY < stage.stageHeight){
 posX = 0;
 j = 0;
 posY = i * buttonSize;
 while(posX < stageWidth){
  posX = j * buttonSize;
  var b:Button = new Button();
  b.setSize(buttonSize,buttonSize);
  b.move(posX, posY);
  b.label = getRandomLetter();
  addChild(b);
  j++;
 }
 i++;
}

あらかじめgetRandomLetter()メソッドが定義されている

var letters:Array = ["A","B","C","D","E","F","G","H","I","J","K","L","M","N","O","P","Q","R"S","T","U","V","W","X","Y","Z"];
function getRandomLetter():String{
 var randomIndex:uint = Math.Floor(Math.random() * letters.length);
 return letters[randomIndex];
}

６.コンパイルするとA～Zをラベルとするボタンがランダムの順序で碁盤状に敷き詰められている７.ボタンサイズとステージサイズを変えて、試し

TextFieldにShapeでマスク

2007-04-25T04:48:49Z

手順メモ。１.テキストフィールド作成

var label:TextField = new TextField();
label.autoSize = TextFieldAutoSize.LEFT;
label.text = "SCRATCHBRAIN.NET";
addChild(label);
label.x = 25;
label.y = 25;

]]>

var square:Shape = new Shape();
addChild(square);
square.graphics.beginFill(0x999999,1.0);
square.graphics.drawRect(25,25,50,50);
square.graphics.endFill();

３.マスク適用

label.mask = square;

参考URL Adobe Flex 2 リファレンスガイド DisplayObjectクラス maskプロパティ

8-1-4.カスタムクラスからのイベント送出その１

2007-04-25T04:28:39Z

カスタムクラスからイベントを送出するようにするにはEventDispatcherクラスを拡張します。すでにほかのクラスを継承している場合は、IEventDispatcherインターフェイスを使います。ここではEventDispatcherクラスを使う場合について取り上げています。 CustomDispatcherクラス作成まず、CustomDispatcherクラスを作成し、イベントの内容を定義します。このクラスはEventDispatcherクラスを継承して作ります。 DisplayObjectContainerクラスがEventDispatcherクラスを継承しているので、CustomDispatcherクラスはSpriteクラスを継承しても作成可能です。１.Eventクラス、EventDispatcherクラスをimport

import flash.events.Event;
import flash.events.EventDispatcher;

２.イベントタイプ作成

public static const START:String = "start";
public static const PROCESSING:String = "processing";
public static const COMPLETE:String = "complete";

３.イベントの内容とイベント送出設定 forループを5回ループすると、処理終了を送出します。その他、処理開始、処理中を送出します。

public function doAction():void {
 // 処理開始送出
 dispatchEvent(new Event(CustomDispatcher.START));
 // イベントの内容
 for (var i:int; i < 5 ; i++) {
  trace(i);
  dispatchEvent(new Event(CustomDispatcher.PROCESSING));
 }
 // 処理終了送出
  dispatchEvent(new Event(CustomDispatcher.COMPLETE));
 }
}

CustomDispatcherクラスのイベント使用次に、MainクラスでCustomDispatcherクラスで定義したイベントを使ってみます。

package {
 import flash.display.Sprite;
 import flash.events.Event;
 public class Main extends Sprite {
  public function Main (){
   var example:CustomDispatcher = new CustomDispatcher();
   example.addEventListener(CustomDispatcher.START,onStart);
   example.addEventListener(CustomDispatcher.PROCESSING,onProcess);
   example.addEventListener(CustomDispatcher.COMPLETE,onComplete);
   example.doAction();
  }
  private function onStart(event:Event):void{
   trace("イベント開始");
  }
  private function onProcess(event:Event):void{
   trace("処理中...");
  }
  private function onComplete(event:Event):void{
   trace("イベント終了");
  }
 }
}

example.doAction()メソッドを実行することによって、イベント処理が開始します。上の処理の出力結果は次のようになります。イベント開始

0
処理中...
1
処理中...
2
処理中...
3
処理中...
4
処理中...
イベント終了

カスタムイベントは上手に使えるようになりたい。参考URL Adobe Flex 2 リファレンスガイド EventDispatcherクラス Adobe Flex 2 リファレンスガイド IEventDispatcherインターフェイス fladdict.net blog AS3メモ Commandライブラリ仕様メモ fladdict.net blog AS3用のCommandライブラリ作ってみた]]>

8-1-3.イベントリスナー

2007-04-23T15:45:54Z

イベントリスナーはイベントに応答して実行される関数で、イベントハンドラとも言います。イベントリスナーはイベントが発生すると、リスナー関数（イベントハンドラ関数）を呼びます。イベントリスナーの登録は次の手順で行います。 btnA.addEventListener(MouseEvent.CLICK, onClickHandler); btnAがクリックされるとonClickHandler()メソッドが呼ばれます。２.ハンドラ関数作成

private function onClickHandler(event:MouseEvent):void{
 trace("Hello !");
}

次に挙げるaddEventListener()メソッドのパラメータのうち、type、listenerは必須です。 typeパラメータ:String Event.ENTER_FRAME、MouseEvent.CLICKなど、イベントのタイプを指定します。 listenerパラメータ:Function typeパラメータで指定したイベントが発生したときに実行するハンドラ関数を指定します。 useCaptureパラメータ:Boolean イベントフローのどの段階の処理をアクティブにするか指定します。trueを指定するとキャプチャ段階のみイベントを処理します。falseを指定すると、ターゲット段階とバブリング段階のイベントを処理します。デフォルトfalse。詳細は『8-1-1.イベントモデルの概要とイベントフロー』をご覧下さい。 priorityパラメータ:int イベントリスナーの優先度を指定します。数が大きいほど先に処理されます。デフォルト0。 priorityパラメータを次のように指定した場合、リスナー関数が実行される順序はonClickHandler1、onClickHandler2、onClickHandler3になります。

square.addEventListener(MouseEvent.CLICK, onClickHandler3,false,0);
square.addEventListener(MouseEvent.CLICK, onClickHandler1,false,1);
square.addEventListener(MouseEvent.CLICK, onClickHandler2,false,1);

useWeakReferenceパラメータ:Boolean リスナー関数への参照を強参照（false）にするか、弱参照（true）にするか指定します。 trueの場合、リスナー関数が使用されなくなった後、メモリから削除されます。デフォルトfalse。イベントリスナーの削除はremoveEventListener()メソッドを使います。

square.removeEventListener(MouseEvent.CLICK, onClickHandler1,false);

イベントリスナーが存在するか確認するにはhasEventListener()メソッドか、willTrigger()メソッドを使います。次のようなイベントリスナーが登録されていたとします。

stage.addEventListener(MouseEvent.CLICK, onClick);

hasEventListener()メソッドパラメータに指定したイベントタイプが存在する場合、trueを返します。存在しない場合、falseを返します。ステージにマウスクリックイベントの登録があるのでtrue、squareにはマウスクリックイベントが登録されていないのでfalseを返します。

trace(stage.hasEventListener(MouseEvent.CLICK));// 出力 true
trace(square.hasEventListener(MouseEvent.CLICK));// 出力 false
trace(stage.hasEventListener(MouseEvent.ROLL_OVER));// 出力 false

willTrigger()メソッド hasEventListener()メソッド同様、パラメータに指定したイベントタイプが存在する場合、trueを返します。存在しない場合、falseを返します。 hasEventListener()メソッドとの違いは、イベントフロー全体に対する結果を返します。したがって、squareに対する結果がhasEventListener()メソッドと異なります。squareのイベントフローにステージが存在する為、square自体にマウスクリックイベントが登録されていなくても、結果はtrueとなります。

trace(stage.willTrigger(MouseEvent.CLICK));// 出力 true
trace(square.willTrigger(MouseEvent.CLICK));// 出力 true
trace(stage.willTrigger(MouseEvent.ROLL_OVER));// 出力 false

参考URL Adobe Flex 2 リファレンスガイド EventDispatcherクラス FumioNonaka.com EventDispatcher.addEventListener()メソッド]]>

ActionScript3.0ゲームプログラミングブック

2007-04-23T15:44:11Z

ゲームプログラミングとタイトルにあるわりにはゲームの話題はほんの少しです。次期Flashに備えてActionScript3.0予習したかったんですが、入門書としてよかったです。 Flash関係の書籍によくある3Dメニューとかそういった表現については書いてありません。

Spriteロールオーバー時に指カーソルにする

2007-04-23T15:32:04Z

buttonModeプロパティにtrueを設定すると、指カーソルになる。サンプルコード

var square:Sprite = new Sprite();
addChild(square);
square.graphics.beginFill(0x999999,1.0);
square.graphics.drawRect(0,0,50,50);
square.graphics.endFill();
square.buttonMode = true;

参考URL Adobe Flex 2 リファレンスガイド Spriteクラス buttonModeプロパティ]]>

トウェルヴ／パティスミス

2007-04-23T15:27:42Z

ビートルズ、ローリングストーンズ、ボブディラン、スティーヴィーワンダーなどカヴァーしています。ドアーズのカヴァーを聴きながら、なんかに似ていると思ったら、コーラルだった。パティスミス自身による曲説明を読むと、どんなにカートコバーンに共感していたかがわかる。カートはマイケルスタイプ（REM）とのコラボを望んでいたようだけど、パティスミスにしろ、キムゴードン（ソニックユース）にしろ、彼に深い愛情と理解を示す人たちが今なお新しい曲を作り続けていることに感動を覚える。これでヴェルヴェットアンダーグラウンドの『オールトゥモローズパーティーズ』あたり入っていたらもっと嬉しかったな。

Adobe Video Workshop その１

2007-04-22T14:21:30Z

AdobeのFlas CS3関連リソースメモ。『Using Flash』から。『Adobe Video Workshop』にCS3のチュートリアル、Tipsなど200以上ある。製品リストからFlash CS3を選ぶと、34のトピックスが出てくる。]]> Creating an effective workflow between design and development デザイナーとデベロッパーのワークフローを紹介。１.デザイナーがステージ上でグラフィックとタイムラインを使って作成２.トゥイーンの設定してあるフレームを選択して右クリック「Copy Motion as ActionScript3.0」を選択３.ActionScriptで使うインスタンス名をなににするか決めて、OKボタンを押す４.クリップボードにActionScript（とmxml）が記憶されているので、第１フレームにペースト５.パブリッシュ Using components コンポーネントの使い方。１.[Window]-[Components]選択し、パネルを表示。２.Buttonをステージにドラッグ３.ステージ上のButtonを選択し、[Parameters]-[label]に任意の名前を設定４.Buttonをダブルクリックし、デザイン変更５.[Control]-[Test Movie]選択 Drawing with the Pen tool ペンツールによる描画。アンカーポイントの操作など。 Working with text テキストツールの使い方。 Using the drawing tools 矩形ツールの使い方。・角丸は角をドラッグすると角度を変えられる・円ツールその２だと、ドーナッツ状にしたり、裂け目を作ったりドラッグで可能・「Object Drawing」ボタンを押すと、矩形を２つ重ねた時に重なった部分が消去されるのを防ぐことができる（Flash8にもある機能） Using the Flash Video Encoder Flash Video Encoder使い方。１.[Add]ボタンを押し、エンコードするムービーファイル選択２.[Settings]ボタンを押し、いろいろ設定３.[Start Queue]ボタンクリック今日見た中だと、「Creating an effective workflow between design and development」が一番見る価値あり。

東京ミッドタウン

2007-04-22T12:34:58Z

土曜日に東京ミッドタウンに行ってきました。 ]]>

8-1-2.イベントオブジェクト

2007-04-20T15:44:25Z

イベントオブジェクトはEventクラスとそのサブクラスを使って作成します。イベントオブジェクトはイベントの種類が何かを表現します。例えば、enterFrameイベントをイベントリスナーに登録するには次のようにします。

square.addEventListener(Event.ENTER_FRAME, onEnterFrameHandler);

]]> bubblesプロパティ読み取り専用。trueの場合、バブリング段階があります。flaseの場合、バブル不可能です。詳しくは『8-1-1.イベントモデルの概要とイベントフロー』をご覧下さい。 cancelableプロパティ読み取り専用。trueの場合、イベントに関連づけられたデフォルト動作をキャンセル可能です。falseの場合、不可。このプロパティがtrueのイベントは少ないようです。調べていて見つけたのは次の３つ。・FocusEvent.KEY_FOCUS_CHANGE ・FocusEvent.MOUSE_FOCUS_CHANGE ・TextEvent.TEXT_INPUT 実際にデフォルト動作をキャンセルするにはpreventDefault()メソッドを使います。ここではTextEvent.TEXT_INPUTで動作確認してみます。次のようなテキスト入力フィールドを作成します。

var input:TextField = new TextField();
addChild(input);
input.type = TextFieldType.INPUT;

当然のことながらフィールドに対して文字入力が可能です。そこで、次のようなイベントを設定してみます。

input.addEventListener(TextEvent.TEXT_INPUT, textInputHandler);

イベントハンドラでpreventDefault()メソッドを呼び出します。

private function textInputHandler(event:TextEvent):void{
 event.preventDefault();
}

こうすると、デフォルト動作がキャンセルされ、テキストフィールドに文字を打とうとしても、反映されません。 eventPhaseプロパティ読み取り専用。イベントがどの段階にあるのか数値で示します。 1であればキャプチャ段階。 2であればターゲット段階。 3であればバブリング段階。 targetプロパティイベントターゲットを示します。例えば、次のような表示リストがあったとします。 squareAとsquareBにマウスイベントを登録します。

squareA.addEventListener(MouseEvent.CLICK, onClickHandler);
squareB.addEventListener(MouseEvent.CLICK, onClickHandler);

ハンドラ関数は次のように設定します。

private function onClickHandler(event:Event):void{
 trace("eventPhase:" + event.eventPhase, " target:" + event.target.name, " currentTarget:" + event.currentTarget.name);
}

squareBをクリックしたときの出力結果は次のようになります。

eventPhase:2  target:squareB  currentTarget:squareB
eventPhase:3  target:squareB  currentTarget:squareA

このようにバブリング段階においてもイベントターゲットはsquareBとなります。イベントターゲットが表示リストに含まれる場合は注意が必要となります。 currentTargetプロパティイベントオブジェクトをアクティブに処理しているオブジェクトを示します。 targetプロパティでの例にある通り、targetプロパティとcurrentTargetプロパティで値が異なるので、状況に応じて使い分ける必要があります。 Eventクラスのサブクラスによっては、MouseEvent.CLICKのshiftKeyプロパティなど、他にもプロパティがあります。参考URL Adobe Flex 2 リファレンスガイド Eventクラス

別冊黒い画集／松本清張

2007-04-20T15:40:52Z

６編からなる短編集。家政婦が派遣された家でその家庭の崩壊を楽しむ『熱い空気』、邪馬台国論争と推理小説をくっつけた『陸行水行』の２編が変わった作品だと思った。

メイクアナザーワールド／アイドルワイルド

2007-04-20T15:34:58Z

ロッキンオンのインタビューによると、「都会」がテーマらしい。「いろんな人達が、いろんなものを持ち寄って、都会という一つの世界を作り上げている。ひとりひとりがこの街に貢献しているし、誰もが日々新たに世界を作り変えてる（引用）」サードアルバム『リモートパート』の邦訳が『ひなびた場所』だったことを思うと、『メイクアナザーワールド』というタイトルには当時よりも力強さを感じる。廃盤になっていたセカンドアルバム『100ブロークンウィンドウズ』をようやくレコファンで見つけて購入。ついでにサード『リモートパート』も。これで４枚目以外揃った。ファーストから順に聞いていくとバンドの軌跡が感じとれる。こうなったら全部揃えるしかない。

8-1-1.イベントモデルの概要とイベントフロー

2007-04-19T18:23:58Z

ボタンがクリックされるなどのユーザー操作や、データのロードが完了した時など、なんらかのトリガによってイベントが発生します。 ActionScript3.0では、イベントをイベントオブジェクトとして、Eventクラスとそのサブクラスのインスタンスで表現します。 import flash.events.MouseEvent; ２.イベントリスナー登録

addChild(btnA);
btnA.name = "A";
btnA.addEventListener(MouseEvent.CLICK, btnAOnClick);

３.イベントに応答するメソッド定義

private function btnAOnClick(event:MouseEvent):void {
 trace(event.currentTarget.name);// 出力 A
}

ここで、イベントオブジェクトの送出先となるオブジェクトbtnAをイベントターゲットと呼びます。上の例ではイベントターゲットにイベントリスナーを登録し、イベントに応答するメソッドbtnAClickHandlerを結び付けています。イベントターゲットが表示リストにない場合は直接イベントターゲットに対してイベントオブジェクトが送出されます。イベントターゲットが表示リストに含まれる場合は、表示リストの階層内を経由して、イベントターゲットまでイベントオブジェクトが送出されます。イベントオブジェクトが表示リスト内を伝播する経路のことをイベントフローと言います。 ActionScript3.0のイベント処理では、イベントフロー、イベントオブジェクト、イベントリスナーが基本概念となります。まずはその中から、イベントフローについて取り上げたいと思います。次のような表示リストがあったとします。イベントフローは３段階に分かれます。キャプチャ段階 btnAがクリックされると、イベントオブジェクトはイベントフローをステージからイベントターゲットに向けて下がっていきます。これをキャプチャ段階と言います。キャプチャ段階ではStageとsquare(Parent Node)が含まれています。ターゲット段階イベントターゲットであるbtnAに到達した段階をターゲット段階と言います。ターゲット段階にはbtnA(Child Node1)が含まれています。バブリング段階イベントオブジェクトは最後にステージに向かって浮上（バブリング）します。これをバブリング段階と言います。バブリング段階ではStageとsquare(Parent Node)が含まれています。各段階で含まれるノードは、イベントに応答することが可能です。次のようにイベントリスナーを登録した場合、btnAに対するイベントにStageやsquareが応答することができます。

stage.addEventListener(MouseEvent.CLICK, onClick);
square.addEventListener(MouseEvent.CLICK, squareOnClick);
btnA.addEventListener(MouseEvent.CLICK, btnAOnClick);

それぞれのリスナー関数には次のような定義をします。

private function onClick(event:MouseEvent):void{
 trace(event.currentTarget.stageHeight);
}
private function squareOnClick(event:MouseEvent):void{
 trace(event.currentTarget.name);
}
private function btnAOnClick(event:MouseEvent):void{
 trace(event.currentTarget.name);
}

btnAをクリックした時の出力結果は次のようになります。

btnA
square
200

squareをクリックした時の出力結果は次のようになります。

square
200

ステージをクリックした時の出力結果は次のようになります。

これはターゲット段階、バブリング段階でリスナー関数が呼び出されているためです。最後の200はステージの高さです。StageクラスにはnameプロパティがないためstageHeightを使いました。上の例を見ると、キャプチャ段階が無視されていることがわかります。キャプチャ段階でリスナー関数を呼び出すにはaddEventListener()の第３引数useCaptureにtrueをセットします。 btnBで試してみます。

btnB.addEventListener(MouseEvent.CLICK, btnBOnClick,true);

btnBのリスナー関数は次のようにしてみます。

private function btnBOnClick(event:MouseEvent):void{
 trace(event.currentTarget.name);
}

btnBをクリックした時の出力結果は次のようになります。

square
200

このようにターゲット段階、バブリング段階は無視されます。『Adob Flex 2 ヘルプイベントの伝播』に次のようにあります。「キャプチャ段階が使用されることはほとんどありません。またキャプチャ段階を使用すると、計算処理の負荷が大きくなります。キャプチャとは逆に、バブリングは頻繁に実行されます。（引用）」また、バブリング段階についても、イベントのタイプによっては処理しない場合があるので注意が必要です。例えばMouseEventのClickイベントがキャプチャ段階やバブリング段階を経るかどうかは、『Adobe Flex 2 リファレンスガイド MouseEventクラス CLICK定数』を見るとわかります。 bubblesプロパティがtrueになっているのでターゲット段階以外のフェーズを経由します。上の例でbtnAを押した時にsquareとステージのリスナー関数を呼び出したくない場合は、次のようにstopPropagation()メソッドを使います。

private function btnAOnClick(event:MouseEvent):void{
 trace(event.currentTarget.name);
 event.stopPropagation();
}